Keyboard shortcuts

Press ← or → to navigate between chapters

Press S or / to search in the book

Press ? to show this help

Press Esc to hide this help

Клиент сервиса на плате

На предыдущей странице компьютер отправлял запрос, а плата его выполняла. Но роли могут поменяться: плата сама может выступить клиентом сервиса и обратиться с запросом к узлу ROS 2 на компьютере — например, попросить компьютер выполнить расчёт, сохранить точку маршрута или подтвердить готовность системы. В этой части урока мы научим плату вызывать сервис /add_two_ints на компьютере по нажатию кнопки D28.

Как устроен вызов сервиса с платы (ros.call())

Проверим работу клиента на стандартном сервисе сложения двух целых чисел example_interfaces/srv/AddTwoInts (#include <example_interfaces/srv/AddTwoInts.h>):

  • в запросе передаются два слагаемых: adder.request.a и adder.request.b;
  • в ответе компьютер возвращает их сумму: srv.response.sum.
sequenceDiagram
    participant B as Плата TurtleBro (клиент)
    participant PC as Узел на компьютере (сервер)
    Note over B: Нажата кнопка D28
    B->>PC: ros.call("add_two_ints") — запрос a=1, b=10
    Note over B: Цикл loop() продолжает работать без паузы
    PC->>B: Ответ sum=11
    Note over B: Вызывается onSumAnswer() — переключает D48

Для отправки запроса используется функция ros.call("имя_сервиса", объект_запроса, функция_ответа):

#include <RosDuino.h>
#include <example_interfaces/srv/AddTwoInts.h>

const int BUTTON_PIN = 28;
const int LED_PIN = 48;

example_interfaces::AddTwoInts adder;
rosduino::Timer buttonTimer(30);

int lastButtonState = LOW;
int counter = 1;

// Вызывается автоматически, когда от компьютера пришёл ответ сервиса.
void onSumAnswer(example_interfaces::AddTwoInts& srv) {
  if (srv.response.sum == srv.request.a + srv.request.b) {
    digitalWrite(LED_PIN, !digitalRead(LED_PIN));
  }
}

void setup() {
  pinMode(BUTTON_PIN, INPUT);
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);

  lastButtonState = digitalRead(BUTTON_PIN);
  ros.begin("add_client_node");
}

void loop() {
  ros.update();

  if (ros.connected() && buttonTimer.check()) {
    int reading = digitalRead(BUTTON_PIN);

    if (reading != lastButtonState) {
      lastButtonState = reading;

      if (lastButtonState == HIGH) {
        adder.request.a = counter;
        adder.request.b = 10;
        counter++;

        // Отправляем неблокирующий запрос сервису "/add_two_ints".
        ros.call("add_two_ints", adder, onSumAnswer);
      }
    }
  }
}

Почему ros.call() не останавливает loop()

Вызов ros.call() работает асинхронно (неблокирующе):

  1. Плата отправляет пакет запроса агенту и сразу продолжает выполнять loop().
  2. Пока компьютер считает и отправляет ответ обратно, ros.update() продолжает обслуживать все остальные топики и таймеры платы.
  3. Как только ответ приходит по USB, библиотека автоматически вызывает функцию onSumAnswer(), передавая в неё структуру srv с заполненным полем srv.response.sum.

Если вызвать ros.call() повторно до того, как пришёл ответ на предыдущий запрос к тому же сервису, функция вернёт rosduino::Result::Busy. Если сервер на компьютере не ответит в течение 1 с, ожидание автоматически сбросится, и сервис можно будет вызвать снова.

Пошаговая проверка с сервером на компьютере

  1. Остановите rosduino_agent в Терминале 1 (Ctrl+C), загрузите скетч в плату и снова запустите агент:

Терминал 1:

ros2 run rosduino_agent rosduino_agent --port /dev/ttyACM0
  1. Во втором окне терминала (Терминал 2) запустите стандартный демонстрационный сервер сложения из комплекта ROS 2:

Терминал 2:

ros2 run demo_nodes_cpp add_two_ints_server
  1. Нажмите кнопку D28 на плате несколько раз.

Ожидаемый результат

При каждом нажатии кнопки D28 в окне Терминала 2 появляется строка Incoming request: [a: 1, b: 10], затем [a: 2, b: 10] и так далее. Светодиод D48 на плате сразу меняет своё состояние, подтверждая, что ответ от компьютера получен и сумма совпала.

Остановите демонстрационный сервер в Терминале 2 клавишами Ctrl+C.

Назад: Сервер сервиса на плате.
Дальше: Создание сообщений для сервисов.