Keyboard shortcuts

Press ← or → to navigate between chapters

Press S or / to search in the book

Press ? to show this help

Press Esc to hide this help

Урок 3. Решение задания

На этой странице разобрано решение задания «Счётчик нажатий со сбросом через Serial». Программа одновременно мигает светодиодом D48, считает нажатия кнопки D28 без дребезга и сбрасывает счётчик при получении символа '0' из утилиты мониторинга порта — и всё это без единого вызова delay().

Полный код скетча

const int BUTTON_PIN = 28;
const int LED_PIN = 48;

const unsigned long BLINK_PERIOD_MS = 500;
const unsigned long BUTTON_POLL_MS = 30;

int pressCount = 0;
int lastButtonState = LOW;
bool ledState = false;

unsigned long lastBlinkTime = 0;
unsigned long lastButtonTime = 0;

void setup() {
  pinMode(BUTTON_PIN, INPUT);
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);

  lastButtonState = digitalRead(BUTTON_PIN);

  Serial.begin(115200);
  Serial.println("Ready! Press D28 to count, send '0' to reset.");
}

void loop() {
  unsigned long now = millis();

  // Задача 1: мигание светодиода D48 каждые 500 мс.
  if (now - lastBlinkTime >= BLINK_PERIOD_MS) {
    lastBlinkTime = now;
    ledState = !ledState;
    digitalWrite(LED_PIN, ledState ? HIGH : LOW);
  }

  // Задача 2: опрос кнопки D28 каждые 30 мс (неблокирующая защита от дребезга).
  if (now - lastButtonTime >= BUTTON_POLL_MS) {
    lastButtonTime = now;
    int reading = digitalRead(BUTTON_PIN);

    if (reading != lastButtonState) {
      lastButtonState = reading;

      if (lastButtonState == HIGH) {
        pressCount++;
        Serial.print("Count: ");
        Serial.println(pressCount);
      }
    }
  }

  // Задача 3: мгновенный приём команды '0' из утилиты мониторинга порта.
  while (Serial.available() > 0) {
    char cmd = Serial.read();

    if (cmd == '0') {
      pressCount = 0;
      Serial.println("Counter reset to 0");
    }
  }
}

Как устроено решение

  1. Фоновое мигание (lastBlinkTime): каждые 500 мс переменная ledState меняет значение на противоположное, а светодиод D48 включается или выключается. Поскольку delay() не используется, проверка занимает всего несколько микросекунд.
  2. Неблокирующий антидребезг кнопки (lastButtonTime): в уроке 2 мы подавляли дребезг с помощью delay(30). Здесь тот же интервал 30 мс отсчитывается через millis(). Микроконтроллер считывает пин кнопки не чаще одного раза в 30 мс, поэтому быстрые колебания контактов остаются незамеченными, а основной цикл loop() ни на миллисекунду не останавливается.
  3. Сброс по команде '0': цикл while (Serial.available() > 0) забирает пришедшие символы из входного буфера. Если пришёл символ '0', переменная pressCount обнуляется, а символы перевода строки ('\n', '\r') просто игнорируются.

Как проверить решение

  1. Загрузите скетч в плату и откройте утилиту мониторинга порта (Монитор порта) на скорости 115200 baud.
  2. В окне появится приветственная строка Ready! Press D28 to count, send '0' to reset., а светодиод D48 на плате начнёт равномерно мигать.
  3. Нажмите кнопку D28 несколько раз. На каждое нажатие в утилите мониторинга порта сразу появится строка:
    Count: 1
    Count: 2
    Count: 3
    
  4. Введите в поле отправки утилиты мониторинга порта цифру 0 и нажмите Enter. В окне появится строка Counter reset to 0.
  5. Нажмите кнопку D28 ещё раз — счёт продолжится с Count: 1.

Ответы на вопросы для самопроверки

  1. Какое примерно значение вернёт analogRead(A8) при стандартной шкале 0–1023, если на вход подать напряжение 1,65 В? Что вернёт analogRead(A8), если к разъёму GPIO вообще не подключён датчик?
    Напряжение 1,65 В — это ровно половина от максимального напряжения 3,3 В, поэтому АЦП вернёт значение около середины шкалы: примерно 511–512. Если датчик не подключён, контакт остаётся неподключённым («плавающим»), улавливает случайные электрические наводки, и analogRead(A8) возвращает произвольные меняющиеся значения.

  2. Что произойдёт в окне утилиты мониторинга порта, если в скетче написано Serial.begin(115200), а в настройках утилиты выбрана скорость 9600 baud?
    Плата и компьютер будут использовать разную длительность одного бита при передаче, поэтому в окне утилиты мониторинга порта вместо читаемого текста появятся нечитаемые символы («кракозябры») или пустой вывод.

  3. Почему в программах для роботов нельзя использовать delay(1000) внутри loop() и какой конструкцией с millis() её заменяют?
    Во время delay(1000) микроконтроллер полностью приостанавливает выполнение цикла loop(): он не может опрашивать кнопки и датчики, не читает входящие команды из Serial и не обслуживает обмен данными с ROS 2. Вместо этого запоминают время последнего срабатывания lastTime и проверяют условие if (millis() - lastTime >= 1000).

  4. В чём разница между функциями map() и constrain()?
    Функция map() пропорционально пересчитывает значение из одного диапазона в другой (но не запрещает выход за границы, если входное значение вышло за пределы исходного диапазона), а функция constrain() жёстко ограничивает значение по заданному минимуму и максимуму.

Назад: Домашнее задание.
Дальше: Урок 4. Первый узел RosDuino.